terraform {
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "~> 5.0"
    }
  }
  backend "s3" {}
}
provider "aws" {
  region = "us-west-2"
}

variable "eks_oidc" {
  type = string
}

variable "env" {
  type = string
}

variable "logical_region_name" {
  type = string
}

variable "controlplane_account" {
  type = string
}

variable "dataplane_accounts" {
  type = list(string)
}

variable "crossplane_role_arn" {
  type = string
}

module "region-server" {
  source = "../../modules/controlplane"

  controlplane_account = var.controlplane_account
  oidc                 = var.eks_oidc
  role_name            = "${var.env}-${var.logical_region_name}-drs"
  service_account      = "dedicated-regional-server-manager"
  policy_document = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Action = "sts:AssumeRole"
        Effect = "Allow"
        Resource = concat(
          # dataplane for dedicated region server
          [for acct in var.dataplane_accounts : "arn:aws:iam::${acct}:role/${var.env}-${var.logical_region_name}-dp4drs"],
          # region-server needs to assume to full-manager-service-role to manage migrated eks cluster
          [for acct in var.dataplane_accounts : "arn:aws:iam::${acct}:role/full-manager-service-role"]
        )
      },
      {
        Action = "iam:ListRoles"
        Effect = "Allow"
        Resource = "*"
      }
    ]
  })
}

# crossplane-provider uses this role to manage controlplane resources for region-server
module "crossplane" {
  source = "../../modules/crossplane"

  assumed_role_name   = "${var.env}-${var.logical_region_name}-dp4drs-gr"
  crossplane_role_arn = var.crossplane_role_arn
  policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Action = [
          "route53:*", # manage route53 DNS recordset
          "iam:*",     # grant dataplane cert-manager to access global PCA
          "ec2:*"      # manage PrivateLink endpoint from seed to dataplane in BYOC
        ]
        Effect   = "Allow"
        Resource = "*"
      }
    ]
  })
}

output "role_arn" {
  value = module.region-server.controlplane_role_arn
}

output "crossplane_assumed_role_arn" {
  value = module.crossplane.assumed_role_arn
}

output "assumed_role_name" {
  value = "${var.env}-${var.logical_region_name}-dp4drs"
}