terraform {
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "~> 5.0"
    }
  }
  backend "s3" {}
}
provider "aws" {
  region = "us-west-2"
}

variable "eks_oidc" {
  type = string
}

variable "env" {
  type = string
}

variable "logical_region_name" {
  type = string
}

variable "controlplane_account" {
  type = string
}

variable "dataplane_accounts" {
  type = list(string)
}

module "ticdc_server" {
  source = "../../modules/controlplane"

  controlplane_account = var.controlplane_account
  oidc                 = var.eks_oidc
  role_name            = "${var.env}-${var.logical_region_name}-ticdc-server"
  service_account      = "ticdc-server"
  policy_document = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Action   = "sts:AssumeRole"
        Effect   = "Allow"
        Resource = "*"
      }
    ]
  })
}

module "ticdc_controller" {
  source = "../../modules/controlplane"

  controlplane_account = var.controlplane_account
  oidc                 = var.eks_oidc
  role_name            = "${var.env}-${var.logical_region_name}-ticdc-controller"
  service_account      = "ticdc-service"
  policy_document = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Action   = "sts:AssumeRole"
        Effect   = "Allow"
        Resource = [for acct in var.dataplane_accounts : "arn:aws:iam::${acct}:role/${var.env}-${var.logical_region_name}-ticdc-controller-assumed-role"]
      },
      { # For retrieving eks ami id
        Action   = "ssm:GetParameter"
        Effect   = "Allow"
        Resource = "*"
      }
    ]
  })
}

output "ticdc_server_role_arn" {
  value = module.ticdc_server.controlplane_role_arn
}

output "ticdc_controller_role_arn" {
  value = module.ticdc_controller.controlplane_role_arn
}

output "ticdc_controller_assumed_role_name" {
  value = "${var.env}-${var.logical_region_name}-ticdc-controller-assumed-role"
}