resource "alicloud_oss_bucket" "shared" {
  bucket = "o11y-${var.env}-shared-${var.logical_region_name}"
  tags   = local.common_tags
}

module "o11y-dataplane" {
  depends_on = [module.cloud-addon-cd]
  source     = "../../modules/app"

  workflow = "new-region-dataplane.yaml"
  gh_repo  = "tidbcloud/observability"
  gh_ref   = "main"
  parameters = {
    vendor            = "alicloud"
    region            = var.cloud_region
    logicalRegionName = var.logical_region_name
    env               = var.env
    cluster           = local.cluster_name
    args = jsonencode({
      vmclusterBucketName    = alicloud_oss_bucket.shared.bucket
      vmclusterRoleArn       = "acs:ram::${local.alicloud_account}:role/vmbackup-${local.cluster_name}"
      lokiBucketName         = alicloud_oss_bucket.loki.bucket
      lokiRoleArn            = "acs:ram::${local.alicloud_account}:role/loki-${local.cluster_name}"
      nginxReadIngressClass  = "nginx-read"
      nginxWriteIngressClass = "nginx-write"
      imageRegistry          = local.image_registry
      hostedZoneName         = var.env == "prod" ? "observability.tidbcloud.com" : "observability-${var.env}.pingcap.cloud"
    })
  }
  wait_workflow_success = true
  finalizer = {
    workflow = "destroy-region-dataplane.yaml"
    parameters = {
      vendor            = "alicloud"
      region            = var.cloud_region
      logicalRegionName = var.logical_region_name
      env               = var.env
    }
  }
}

module "o11y-dataplane-cd" {
  depends_on = [module.o11y-dataplane]
  source     = "../../modules/app"

  kubeconfig_path = module.kubeconfig.path
  workflow        = "dataplane-cd.yaml"
  gh_repo         = "tidbcloud/observability"
  gh_ref          = "main"
  parameters = {
    vendor  = "alicloud"
    region  = var.logical_region_name
    env     = var.env
    git-ref = "main"
  }
  services = [
    {
      name      = "sts/vmstorage-vmcluster"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "sts/vmselect-vmcluster"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "deploy/vminsert-vmcluster"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "sts/alertmanager-alert-regional"
      namespace = "default"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    }
  ]
  wait_workflow_success = true
  check_before_destroy  = false
}