module "o11y-dataplane" {
  depends_on = [
    module.cloud-addon-cd,
    azurerm_storage_container.o11y,
  ]
  source = "../../../modules/app"

  workflow = "new-region-dataplane.yaml"
  gh_repo  = "tidbcloud/observability"
  gh_ref   = local.o11y_workflow_ref
  parameters = merge(local.metadata_parameters, {
    args = jsonencode({
      vmclusterRoleARN       = local.identity_client_ids.vmbackup
      lokiRoleARN            = local.identity_client_ids.loki
      storageAccountName     = azurerm_storage_account.o11y.name
      vmclusterBucketName    = local.vmbackup_container
      lokiBucketName         = local.loki_container
      nginxReadIngressClass  = "nginx-read"
      nginxWriteIngressClass = "nginx-write"
      imageRegistry          = var.image_registry
      hostedZoneName         = local.hosted_zone_name
      tenantID               = var.byoc_tenant_id
      byoc                   = true
    })
  })
  wait_workflow_success = true
  finalizer = {
    workflow = "destroy-region-dataplane.yaml"
    parameters = {
      vendor            = "azure"
      region            = var.cloud_region
      logicalRegionName = var.logical_region_name
      env               = var.env
    }
  }
}

module "o11y-dataplane-cd" {
  depends_on = [module.o11y-dataplane]
  source     = "../../../modules/app"

  kubeconfig_path = module.kubeconfig.path
  workflow        = "dataplane-cd.yaml"
  gh_repo         = "tidbcloud/observability"
  gh_ref          = local.o11y_workflow_ref
  parameters      = local.cd_parameters
  services = [
    {
      name      = "sts/vmstorage-vmcluster"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "sts/vmselect-vmcluster"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "deploy/vminsert-vmcluster"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "sts/loki-ha-write"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "deploy/loki-ha-read"
      namespace = "observability"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "sts/alertmanager-alert-regional"
      namespace = "default"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    }
  ]
  wait_workflow_success = true
  check_before_destroy  = false
}