data "kubernetes_nodes" "this" {
  depends_on = [module.kubeconfig, module.aks]
}

module "o11y-infra" {
  source = "../../../modules/app"
  depends_on = [
    module.register-region-meta,
    null_resource.o11y_identity_prerequisites,
    azurerm_storage_container.o11y,
    azurerm_storage_management_policy.o11y,
    aws_cloudwatch_metric_alarm.watchdog_down,
    aws_cloudwatch_metric_alarm.alertmanager_failed_to_send,
  ]

  workflow = "new-region-infra.yaml"
  gh_repo  = "tidbcloud/observability"
  gh_ref   = local.o11y_workflow_ref
  parameters = merge(local.metadata_parameters, {
    args = jsonencode({
      alertmanagerRoleArn    = aws_iam_role.dms.arn
      regionalServerRoleARN  = local.identity_client_ids.regional_server
      o11yBackupRoleArn      = local.identity_client_ids.velero
      o11yBackupBucket       = local.velero_cluster_backup_container
      nginxReadIngressClass  = "nginx-read"
      nginxWriteIngressClass = "nginx-write"
      imageRegistry          = var.image_registry
      hostedZoneName         = local.hosted_zone_name
      subscriptionID         = var.customer_subscription_id
      storageResourceGroup   = var.storage_resource_group_name
      storageAccountName     = azurerm_storage_account.o11y.name
      tenantID               = var.byoc_tenant_id
      byoc                   = true
    })
  })
  wait_workflow_success = true
  finalizer = {
    workflow = "destroy-region-infra.yaml"
    parameters = {
      vendor            = "azure"
      region            = var.cloud_region
      logicalRegionName = var.logical_region_name
      env               = var.env
    }
  }
}

module "o11y-infra-cd" {
  depends_on = [module.o11y-infra]
  source     = "../../../modules/app"

  kubeconfig_path = module.kubeconfig.path
  workflow        = "infra-cd-v2.yaml"
  gh_repo         = "tidbcloud/observability"
  gh_ref          = local.o11y_workflow_ref
  parameters      = local.cd_parameters
  services = [
    {
      name      = "deploy/eventrouter"
      namespace = "kube-system"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "deploy/volume-autoscaler"
      namespace = "self-monitoring"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "deploy/victoria-metrics-operator"
      namespace = "self-monitoring"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "sts/prometheus-self-monitoring-kube-prome-prometheus"
      namespace = "self-monitoring"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "sts/alertmanager-self-monitoring-kube-prome-alertmanager"
      namespace = "self-monitoring"
      wait_for  = "jsonpath='{.status.availableReplicas}'=REPLICAS"
    },
    {
      name      = "ds/self-vector"
      namespace = "self-monitoring"
      wait_for  = "jsonpath='{.status.numberReady}'=${length(data.kubernetes_nodes.this.nodes)}"
    }
  ]
  wait_workflow_success = true
  check_before_destroy  = false
}